// ************************************************************************** //
//                                                                            //
//    eses                   eses                                             //
//   eses                     eses                                            //
//  eses    eseses  esesese    eses   Embedded Systems Group                  //
//  ese    ese  ese ese         ese                                           //
//  ese    eseseses eseseses    ese   Department of Computer Science          //
//  eses   eses          ese   eses                                           //
//   eses   eseses  eseseses  eses    University of Kaiserslautern            //
//    eses                   eses                                             //
//                                                                            //
// ************************************************************************** //
// This module implements carry-ripple addition of B-complement numbers.      //
// Carry-ripple addition has depth O(N) and is therefore not optimal.         //
// ** Note: We are only interested in even values of B **                     // 
// ************************************************************************** //

package Arithmetic.RadixB;
import Arithmetic.RadixB.*;

macro B = 4;    // base of the radix numbers
macro N = 4;    // number of digits used

macro alpha(x) = (x<B/2 ? +x : +x-B);
macro gamma(y) = (y<0 ? y+B : y);
macro dval(x,i,k) = (i==k-1 ? alpha(x[i]) : +x[i]);
macro intval(x,k) = sum(i=0..k-1) (dval(x,i,k) * exp(B,i));


module IntAddCRA([N]nat{B} ?x,?y,[N+1]nat{B} s) {
    event [N]nat{2} c; // carry digits
    assert(B==2*(B/2));       // check that B is even
    c[0] = 0;
    for(i=0..N-2)
        FA: FullAdd(x[i],y[i],c[i],c[i+1],s[i]);
    BC: FullAddBC(x[N-1],y[N-1],c[N-1],s[N],s[N-1]);
    assert(intval(s,N+1) == intval(x,N) + intval(y,N));
}
drivenby Test01 {
    x[N-1] = 0;
    y[N-1] = 0;
    for(i=0..N-2) {
        x[i] = i % B;
        y[i] = (N+i) % B;
    }
}
drivenby Test02 {
    x[N-1] = 0;
    y[N-1] = 1;
    for(i=0..N-2) {
        x[i] = (2*i+1) % B;
        y[i] = (N+2*i) % B;
    }
}