// ************************************************************************** //
//                                                                            //
//    eses                   eses                                             //
//   eses                     eses                                            //
//  eses    eseses  esesese    eses   Embedded Systems Group                  //
//  ese    ese  ese ese         ese                                           //
//  ese    eseseses eseseses    ese   Department of Computer Science          //
//  eses   eses          ese   eses                                           //
//   eses   eseses  eseseses  eses    University of Kaiserslautern            //
//    eses                   eses                                             //
//                                                                            //
// ************************************************************************** //
// The following module computes the roots and the leafs of a graph in O(1)   //
// time using O(N^2) processors using concurrent writing.                     //
// ************************************************************************** //

macro N = 9;


module RootAndLeafs([N][N]bool ?a,[N]bool noRoot,noLeaf) {

    // check all edges and notify the result by concurrent writes
    for(i=0..N-1)
        for(j=0..N-1)
            if(a[i][j]) {
                noRoot[j] = true;
                noLeaf[i] = true;
            }
}
drivenby g1 {
    // the assignments below construct the following graph:
    //
    //                 3
    //                / \
    //               v   v
    //    0 -> 1 <-> 2-> 4 <-> 5 <-> 6
    //               |         |
    //               v         v
    //               7<|       8
    //               |_|
    //
    a[0][1] = true;
    a[1][2] = true;
    a[2][1] = true;
    a[2][4] = true;
    a[2][7] = true;
    a[3][2] = true;
    a[3][4] = true;
    a[4][5] = true;
    a[5][4] = true;
    a[5][6] = true;
    a[5][8] = true;
    a[6][5] = true;
    a[7][7] = true;
    for(i=0..N-1) {
        assert(noRoot[i] == !(i==0 | i==3));
        assert(noLeaf[i] == !(i==8));
    }
}